_ [ahk]CPU/メモリ使用率メータ

前に作ったCPUメータを AHK で書き直してみた。 付属の AHK2Exe で exe にして完璧。

合ってるのかどうかは知らんけど、forumから拾ってきたやつを動くようにして、

; SetTaskbarProgress  -  Requires Windows 7.
;
; pct    -  A number between 0 and 100 or a state value (see below).
; state  -  "N" (normal), "P" (paused), "E" (error) or "I" (indeterminate).
;           If omitted (and pct is a number), the state is not changed.
; hwnd   -  The ID of the window which owns the taskbar button.
;           If omitted, the Last Found Window is used.
;
SetTaskbarProgress(pct, state="", hwnd="")
{
    static tbl, s0:=0, sI:=1, sN:=2, sE:=4, sP:=8
    ; Create a TaskbarList object with ITaskbarList3 interface:
    if !tbl
       tbl := ComObjCreate("{56FDF344-FD6D-11d0-958A-006097C9A090}","{ea1afb91-9e28-4b86-90e9-9e9f8a5eefaf}")
    if hwnd =
        hwnd := WinExist()
    if pct is not number
        state := pct, pct := ""
    else if (pct = 0 && state="")
        state := 0, pct := ""
    if state in 0,I,N,E,P   ; ITaskbarList3::SetProgressState
        DllCall(NumGet(NumGet(tbl+0)+10*A_PtrSize), "ptr", tbl, "uint", hwnd, "uint", s%state%)
    if pct !=               ; ITaskbarList3::SetProgressValue
        DllCall(NumGet(NumGet(tbl+0)+9*A_PtrSize), "ptr", tbl, "uint", hwnd, "int64", pct*10, "int64", 1000)
}

CPU なら 「流行らせるページ」のサンプルからパクってきてこう。

Gui, Show
Gui, +LastFound
SetTaskbarProgress(0, "N")
DllCall("GetSystemTimes","int64p",lastTimeIdle,"int64p",lastTimeKernel,"int64p",lastTimeUser)
Loop
{
  Sleep 500
  DllCall("GetSystemTimes","int64p",TimeIdle,"int64p",TimeKernel,"int64p",TimeUser)
  cpu:=100-100*(TimeIdle-lastTimeIdle)/(TimeUser-lastTimeUser+TimeKernel-lastTimeKernel)
  SetTaskbarProgress(cpu)
  lastTimeIdle=%TimeIdle%
  lastTimeKernel=%TimeKernel%
  lastTimeUser=%TimeUser%
}
GuiClose:
GuiEscape:
ExitApp

メモリは簡単にできる。これは forum からパクった。memst+4 っていうのが何なのかは調べてない。

Gui, Show
Gui, +LastFound
SetTaskbarProgress(0, "P")
VarSetCapacity(memst, 100)
Loop
{
  Sleep 500
  DllCall("GlobalMemoryStatus","uint",&memst)
  mem:=*(&memst+4)
  SetTaskbarProgress(mem)
}
GuiClose:
GuiEscape:
ExitApp

まあ動いてるからいいかな。